Define the model:

model = SM

Define containers for electrons and muons (and photons):

alias lep = e1:E1:e2:E2
alias prt = lep:A

The Born process and additional bremsstrahlung photon, compilation:

process bornproc = e1, E1 => e2, E2
process rc = e1, E1 => e2, E2, A
compile

Avoiding soft and collinear singularities (very mildly):

cuts = all E >= 100 MeV [prt]
   and all abs (cos(Theta)) <= 0.99 [prt]
   and all M2 >= (1 GeV)^2 [prt, prt]

Define title etc. as global variables, that will be used by PLOT:

$description = "A WHIZARD 2.0 Example"
$xlabel = "$\sqrt{s}$/GeV"
$ylabel = "$\sigma(s)$/pb"

Allocate one plot

$title = "The Z Lineshape in $e^+e^-\to\mu^+\mu^-$"
plot lineshape_born { x_min = 88 GeV x_max = 95 GeV)

Allocate another plot

$title = "The Z Lineshape in $e^+e^-\to\mu^+\mu^-\gamma$"
plot lineshape_rc { x_min = 88 GeV x_max = 95 GeV)

Scanning in steps over the collider energy, integrating both Born and radiative corrections:

scan sqrts = ((88.0 GeV => 90.0 GeV /+ 0.5 GeV),
              (90.1 GeV => 91.9 GeV /+ 0.1 GeV),
              (92.0 GeV => 95.0 GeV /+ 0.5 GeV)) {
  beams = e1, E1
  integrate (bornproc) { iterations = 1:2000 }
  record lineshape_born (sqrts, integral (bornproc) / 1000)
  integrate (rc)   { iterations = 5:5000 }
  record lineshape_rc (sqrts, integral (rc) / 1000)
}

Write out the analysis:

compile_analysis { $out_file = "Z-lineshape.dat" }