Select the minimal supersymmetric standard model

model = MSSM

and consider a decay cascade of up-squarks into neutralinos and selectrons

process dec_su_q        = su1 => u, neu2
process dec_neu_sl2     = neu2 => SE12, e1

where the up-squark pairs are generated from up quarks

process susybg = u,U => SU1, su1

We will compare the results with the full process including all irreducible backgrounds

process fullproc = u, U => SU1, u, e1, SE12

Call O'Mega and compile the matrix elements

compile

We use the SLHA convention to choose the SPS1a parameter point

?slha_read_decays = true
read_slha("sps1ap_decays.slha")

Obtain the total widths (simple integration, no singularities, not too many points required)

integrate (dec_su_q, dec_neu_sl2) { iterations = 1:1000 }

We're at the full energy LHC

sqrts = 14000
beams = p, p => lhapdf

Obtain the up-squark production cross section and the cross section for full process

integrate (susybg) { iterations = 5:10000, 2:10000 }
integrate (fullproc)

Simulate 10K events

n_events = 10000

Allocate histograms

$title = "Full process"
$description = 
  "$p + p \to u+ \bar u \to \bar{\tilde u}_1 + u + \tilde e_{12}^+ + e^-$"
$xlabel = "$M_{\rm inv}(ue^-)$"
histogram inv_mass1_full (0,600,20)

$title = "Factorized process with complete spin correlations"
$description = 
  "$p + p \to u\bar u \to \bar{\tilde u}_1 + 
  (\tilde u_1 \to u + (\tilde\chi_2^0 \to \tilde e_{12}^+ + e^-))$"
histogram inv_mass1 (0,600,20)

$title = "Factorized process with classical spin correlations"
histogram inv_mass1_dia (0,600,20)

$title = "Factorized process with isotropic decay"
histogram inv_mass1_iso (0,600,20)

Simulate the full process

simulate (fullproc) {
  $sample = "casc_dec_full"
  analysis = 
    record inv_mass1_full (eval M / 1 GeV [combine[u,e1]])
}

Simulate the cascade decay, including all off-diagonal spin correlations

unstable neu2 (dec_neu_sl2)
unstable su1 (dec_su_q)
unstable neu2 (dec_neu_sl2)
simulate (susybg) {
  $sample = "casc_dec"
  analysis = 
    record inv_mass1 (eval M / 1 GeV [combine[u,e1]])
}

Simulate the cascade decay, keeing only the classical (diagonal) spin correlations

?diagonal_decay = true
unstable su1 (dec_su_q)
unstable neu2 (dec_neu_sl2)
simulate (susybg) {
  $sample = "casc_dec_dia"
  analysis = 
    record inv_mass1_dia (eval M / 1 GeV [combine[u,e1]])
}

Simulate the cascade decay, dropping all spin correlations (i.e. assume isotropic decays)

?isotropic_decay = true
unstable su1 (dec_su_q)
unstable neu2 (dec_neu_sl2)
simulate (susybg) {
  $sample = "casc_dec_iso"
  analysis = 
    record inv_mass1_iso (eval M / 1 GeV [combine[u,e1]])
}

Write the results to file

write_analysis
compile_analysis { $out_file = "casc_dec.dat" }

Running this script​, we obtain terminal output​ and PDF/PS files displaying separate histograms​.

NB: since there's also the histogram data​, one can use gamelan magick​ (or ROOT etc.) to produce a plot with combined histograms​.