Ticket #250: casc_dec_top.sin

model = SM

process dec_top         = t -> b, E1, n1
process dec_top2        = t -> b, Wp
process dec_wplus       = Wp -> E1, n1

process toppair = e1, E1 -> T, t
process full = e1, E1 -> T, E1, n1, b {$restrictions = "4+5+6~t"}

compile


integrate (dec_top, dec_top2, dec_wplus) { iterations = 1:1000 }

sqrts = 500
beams = e1,E1

integrate (toppair) { iterations = 5:10000, 2:10000 }
integrate (full)


n_events = 100000

$title = "Full process"
histogram ang_0 (0,3.1415,0.05)

$title = "Factorized process w 3body/spin"
histogram ang_1 (0,3.1415,0.05)

$title = "Factorized process w 2x2body/spin"
histogram ang_2 (0,3.1415,0.05)

$title = "Factorized process w 3body/iso"
histogram ang_3 (0,3.1415,0.05)

$title = "Factorized process w 2x2body/iso"
histogram ang_4 (0,3.1415,0.05)

simulate (full) {
  $file_raw = "casct2_dec_full.evx"
  analysis = 
    record ang_0 (eval Theta [T,E1])
}

unstable t (dec_top)

simulate (toppair) {
  $file_raw = "casct2_dec_3b.evx"
  analysis = 
    record ang_1 (eval Theta [T,E1])
}

unstable t (dec_top2)
unstable Wp (dec_wplus)

simulate (toppair) {
  $file_raw = "casct2_dec_2b.evx"
  analysis = 
    record ang_2 (eval Theta [T,E1])
}

?isotropic_decay = true
unstable t (dec_top)

simulate (toppair) {
  $file_raw = "casct2_dec_3b_iso.evx"
  analysis = 
    record ang_3 (eval Theta [T,E1])
}

?isotropic_decay = true
unstable t (dec_top2)
unstable Wp (dec_wplus)

simulate (toppair) {
  $file_raw = "casct2_dec_2b_iso.evx"
  analysis = 
    record ang_4 (eval Theta [T,E1])
}

write_analysis
$analysis_filename = "casct2_dec"
write_analysis